שיתוף | קוד לעיצוב חלון בתוכנת Publisher

[מאקרו]

מצורף כאן פקודת מאקרו ל-Publisher שכתבתי עבור עיצוב חלון בתחילת הפסקה כפי שנהוג בספרי קודש.
העקרון של הקוד בנוי על עיצוב המילה הראשונה למודגשת, החלפת הרווח לרווח קשיח (כדי שלא יהיה הבדל בין השורה הראשונה לשניה), והעתקת המילה הראשונה לתחילת השורה שתחתיה כשהיא מעוצבת ללא צבע מילוי.
ניתן לבחור מספר פסקאות ברצף שעליהם יחול העיצוב.
כרגע הקוד לא מבחין בין פסקה עם שורה בודדת או יותר והעיצוב יחול בכל מקרה.
כמו"כ ברשימת הפעולות האחרונות כל פקודה תופיע כרצף של מספר פעולות, ובשביל לבטל יש לבטל את כולם.

Sub חלון()

Dim TxtRng As TextRange, Count As Long

'עבור לתחילת הפסקה
Selection.TextRange.Expand pbTextUnitParagraph
Count = Selection.TextRange.ParagraphsCount
Selection.TextRange.Collapse pbCollapseStart
Set TxtRng = Selection.TextRange
For i = 1 To Count
DoEvents
    'החלף רווח ברווח קשיח
    With TxtRng.Find
        .FindText = " "
        .ReplaceScope = pbReplaceScopeOne
        .Forward = True
        .ReplaceWithText = ChrW$(8194)
        .Execute
        Set TxtRng = .FoundTextRange
    End With
        'עצב מילת פתיח
    With TxtRng
        .MoveStart pbTextUnitLine, -1
        .Font.BoldBi = msoTrue
        .Font.SizeBi = .MajorityFont.SizeBi + 3
        .Font.Name = .Font.Name
        'העתק לשורה שניה
        .Copy
        .Move pbTextUnitLine, 1
        .Paste.Font.Fill.Visible = msoFalse
    End With
    TxtRng.Move pbTextUnitParagraph, 1
Next
End Sub

ניתן לשנות את הערכים הבאים על מנת להתאים אותם באופן אישי:
בשורה 24 מוגדר שהגופן יהיה מודגש, ניתן לשנות לרגיל ע"י msoFalse.
בשורה 25 מוגדר להגדיל את מילת הפתיח ב-3 נק', ניתן לשנות כפי הצורך.
בשורה 26 מוגדר שם הגופן, ובקוד הנ"ל הגדרתי לגופן הנוכחי, ניתן לכתוב את שם הגופן הרצוי בתוך מרכאות. לדוגמא:

  .Font.Name = "Arial"

בתקוה לשימוש מועיל ויעיל.
אשמח לקבל תגובות.