בקשת מידע | חישוב תאריך

האדם השלישי

@צמצם ראשית כל סליחה שלא התפניתי להתייחס לדברים הנפלאים שכתבת ותודה רבה

אך כשניסיתי להסתדר עם זה ראיתי א. שלא הסברתי את עצמי טוב.
ב. שלא הדשלמתי את הבקשה (חשבתי שאח"כ אני יצליח להוסיף לזה עוד דברים)
ומה שאני צריך למעשה כדלהלן: אף ב 15 לחודש אני צריך שזה יהיה כמו ה 10 שזה יהיה תמיד הבא (כגון שאם יהיה כתוב ב A1 את התאריך 20/12/25 יהיה כתוב בתא ב' 15/1/26 ) וכן אני צריך אפשרות של אופציה שיכתוב בתא ב' (ע"פ כיתוב אחר נוסף) את אותו תאריך שכתוב בתא A1
נ.ב. בתא C1 יהיה כיתוב בעברית
אשמח מאוד אם יוכלו לעזור לי בזה (ואולי גם אם עוד נוסחה אני יצליח ללמוד יותר טוב איך הנוסחה עובדת)
תודה רבה

אופיר123

@האדם-השלישי
קובץ דוגמה להורדה
מקווה שקלעתי למה שהתכוונת, תעדכן...
אנסה להסביר בקצרה איך זה עובד, הנוסחה IF מקבלת שלושה ארגומנטים [=נתונים], הראשון הוא תנאי לבדיקה (בדוגמה שם - האם תא B2 כתוב בו "כן". כל טקסט שמכניסים בנוסחה צריך להיות מוקף במרכאות כפולות). אם כן, הנוסחה מחזירה את מה שכתבת בארגומנט השני. אם לא, כלומר אם בתא B2 לא כתוב "כן" (לא משנה מה כן כתוב...) הנוסחה תחזיר את מה שכתבת בארגומנט השלישי.
ושוב גם בארגומנט השלישי כתבתי IF, אם היום קטן מ-15 (ע"י שמכניסים את התאריך לנוסחה DAY מקבלים את מספר היום) או לא.
לפי ההיגיון הזה זה די מובן. מקווה שהסברתי ברור.

חכמון

@צמצם כתב בבקשת מידע | חישוב תאריך:

@האדם-השלישי
ניתן לבצע זאת באקסל באמצעות שילוב של הפונקציות IF (לבדיקת התנאים), DATE (לבניית התאריך), YEAR, MONTH, ו-DAY (לפירוק התאריך המקורי).

להלן הנוסחה שיש להדביק בתא ב' (בהנחה שהתאריך נמצא בתא A1 והמספר 1 או 2 נמצא בתא C1):

Excel

=IF(C1=1, DATE(YEAR(A1), MONTH(A1), 15), IF(C1=2, IF(DAY(A1)<10, DATE(YEAR(A1), MONTH(A1), 10), DATE(YEAR(A1), MONTH(A1)+1, 10)), ""))
הסבר לוגיקת הנוסחה:
החלק הראשון (C1=1): הנוסחה בודקת האם בתא C1 כתוב 1. אם כן, היא לוקחת את השנה והחודש מתא A1 ופשוט קובעת את היום ל-15. זה תואם לדוגמאות שלך (14/12 ו-1/12 שניהם הופכים ל-15/12).

החלק השני (C1=2): אם בתא C1 לא כתוב 1, הנוסחה בודקת אם כתוב 2. במידה וכן, מתבצעת בדיקה נוספת על היום בחודש (פונקציית DAY):

אם היום קטן מ-10 (למשל 1/12): התאריך שייקבע הוא ה-10 לאותו חודש נוכחי.

אם היום הוא 10 ומעלה (למשל 14/12): התאריך שייקבע הוא ה-10 לחודש הבא (MONTH(A1)+1).

הערה חשובה לגבי המעבר בין שנים: פונקציית DATE באקסל היא חכמה. אם הנוסחה מוסיפה 1 לחודש דצמבר (חודש 12 + 1 = 13), אקסל ידע אוטומטית להעביר זאת לחודש ינואר של השנה הבאה. כך שבדוגמה שלך, ה-14/12 אכן יהפוך ל-10/1 בשנה החדשה ללא צורך בתיקון נוסף.

טיפ: אם האקסל שלך מוגדר בעברית/ישראל, ייתכן שתצטרך להשתמש בנקודה-פסיק (;) במקום פסיק (,) בין חלקי הנוסחה. במקרה כזה הנוסחה תיראה כך: =IF(C1=1; DATE(YEAR(A1); MONTH(A1); 15); IF(C1=2; IF(DAY(A1)<10; DATE(YEAR(A1); MONTH(A1); 10); DATE(YEAR(A1); MONTH(A1)+1; 10)); ""))

בינה מלאכותית?!

צמצם

@חכמון כן...

פשוט לא הבנתי עד הסוף מה הוא מבקש, אז ביקשתי מג'ימייני וזה מה שהוא נתן לי...

ישיבישער

@צמצם כתב בבקשת מידע | חישוב תאריך:

פשוט לא הבנתי עד הסוף מה הוא מבקש, אז ביקשתי מג'ימייני וזה מה שהוא נתן לי...

ממש חבל, זה פורום על רמה, אם הוא היה רוצה לשאול את הבינה מלאכותית הוא לא היה צריך אותך לזה.

מתוך חוקי הפורום: מטרת הפורום היא לתת תשובה מדויקת ומקצועית לשואל על-פי המידע והניסיון האישי של המשתמשים העונים, ולכן אין להגיב לשואל במענה ממנוע בינה מלאכותית כמו "צ'אט GPT" וכד', השואל יכול לעשות זאת בעצמו ולא לשם כך הוא פתח את הנושא.

צמצם

@ישיבישער מתנצל.

האדם השלישי

@אופיר123 כתב בבקשת מידע | חישוב תאריך:

מקווה שקלעתי למה שהתכוונת, תעדכן...

דבר ראשון תודה רבה
אבל זה לא בדיוק מה שהתכוונתי
ואני מצרף כאן קובץ שאולי כאן אני יצליח להסביר ברור מה אני רוצה

ניסתי לתרגם את הנוסחה לבד למה שאני צריך, ואני לא יודע למה לא הצלחתי אם חסר לי סוגריים או משהו אחר

חכמון

@האדם-השלישי
זה הנוסחה שאתה צריך להכניס בתא B1:

=IF(C1="א",IF(A1>DATE(YEAR(A1),MONTH(A1),15),EDATE(DATE(YEAR(A1),MONTH(A1),15),1),DATE(YEAR(A1),MONTH(A1),15)),IF(C1="ב",IF(A1>DATE(YEAR(A1),MONTH(A1),10),EDATE(DATE(YEAR(A1),MONTH(A1),10),1),DATE(YEAR(A1),MONTH(A1),10)),IF(OR(C1="ג",C1="ד",C1="ה",C1="ו"),A1,IF(C1="ז","","לא מולא אות"))))

עבדתי על זה כחצי שעה,
וללא עזרת בינה מלאכותית,
אם אתה חושב שמגיע לי על זה משהו,
תוכל לתרום לי.

אין לי לאן להפנות אותך לקרוא על זה,
כי זה היגיון וראש בריא לשלב בין הנוסחאות של התאריכים,
וליצור פונקציות לכל סוג של מקרה.

יוסי מחשבים

@חכמון או יותר קצר:

=IF(C2="א", IF(A2<DATE(YEAR(A2),MONTH(A2),15), DATE(YEAR(A2),MONTH(A2),15), DATE(YEAR(EDATE(A2,1)),MONTH(EDATE(A2,1)),15)), IF(C2="ב", IF(A2<DATE(YEAR(A2),MONTH(A2),10), DATE(YEAR(A2),MONTH(A2),10), DATE(YEAR(EDATE(A2,1)),MONTH(EDATE(A2,1)),10)), IF(OR(C2="ג",C2="ד",C2="ה",C2="ו"), A2, IF(C2="ז","", ""))))

צריך שעמודה B תוגדר כ"תאריך"

קרדיט: GPT
כתבתי לו כך:
אני רוצה נוסחה לאקסל: בעמודה A יש לי רשימה של תאריכים. אני רוצה שאם בעמודה C רשום "א" בטור B יופיע תאריך ה-15 הקרוב אחרי התאריך שבעמודה A (לדוגמא: אם בעמודה A מופיע 20/12 בעמודה B יופיע 15/1) אם בעמודה C רשום "ב" בטור B יופיע תאריך ה-10 הקרוב אחרי התאריך שבעמודה A (לדוגמא: אם בעמודה A מופיע 20/12 בעמודה B יופיע 10/1) אם בעמודה C רשום "ג" או "ד" או "ה" או "ו" בטור B יופיע אותו תאריך שכתוב בעמוד A אם בעמודה C רשום "ז" התא בעמוד C יהיה ריק

חכמון

@יוסי-מחשבים אבל התוצאה שלו אינה נכונה,
אי אפשר לסמוך עליו.

(כתבת החודש שאחריו, אבל אם אנחנו עדיין ב-3 לחודש - הוא כן רוצה את ה-15 באותו חודש,
בוא נראה אם הוא יצליח יותר לקצר ממני).

עריכה: התוצאה כן נכונה, אבל לא כתבת נכון,
תכתוב לו כך:
אני רוצה נוסחה לאקסל: בעמודה A יש לי רשימה של תאריכים. אני רוצה שאם בעמודה C רשום "א" בטור B יופיע תאריך ה-15 הקרוב אחרי התאריך שבעמודה A (לדוגמא: אם בעמודה A מופיע 20/12 בעמודה B יופיע 15/1) או היום עצמו, אם כתוב בעמודה A תאריך 15,
אם בעמודה C רשום "ב" בטור B יופיע תאריך ה-10 לחודש הקרוב אחרי התאריך שבעמודה A (לדוגמא: אם בעמודה A מופיע 20/12 בעמודה B יופיע 10/1) או היום עצמו, אם כתוב בעמודה A תאריך 10,
אם בעמודה C רשום "ג" או "ד" או "ה" או "ו" בטור B יופיע אותו תאריך שכתוב בעמוד A אם בעמודה C רשום "ז" התא בעמוד C יהיה ריק, ואם יש משהו אחר בעמודה C או שזה ריק, שיהיה כתוב לא מולא אות.

יוסי מחשבים

@חכמון תוקן, רק שיניתי במקום "חודש הבא" ל"קרוב".

חכמון

@יוסי-מחשבים אין שום התייחסות בנוסחה שלך ל-ג ד ה ו ז או ריק.
רציתי לראות אם הוא אכן יכול לקצר,
אז אני רוצה שתכניס את כל מה שכתבתי.

אני רוצה נוסחה לאקסל: בעמודה A יש לי רשימה של תאריכים. אני רוצה שאם בעמודה C רשום "א" בטור B יופיע תאריך ה-15 הקרוב אחרי התאריך שבעמודה A (לדוגמא: אם בעמודה A מופיע 20/12 בעמודה B יופיע 15/1) או היום עצמו, אם כתוב בעמודה A תאריך 15,
אם בעמודה C רשום "ב" בטור B יופיע תאריך ה-10 לחודש הקרוב אחרי התאריך שבעמודה A (לדוגמא: אם בעמודה A מופיע 20/12 בעמודה B יופיע 10/1) או היום עצמו, אם כתוב בעמודה A תאריך 10,
אם בעמודה C רשום "ג" או "ד" או "ה" או "ו" בטור B יופיע אותו תאריך שכתוב בעמוד A אם בעמודה C רשום "ז" התא בעמוד C יהיה ריק, ואם יש משהו אחר בעמודה C או שזה ריק, שיהיה כתוב לא מולא אות.

יוסי מחשבים

@חכמון כתב בבקשת מידע | חישוב תאריך:

אז אני רוצה שתכניס את כל מה שכתבתי.

התשובה:

=IF(C2="ז","", IF(C2="א", IF(DAY(A2)<=15, DATE(YEAR(A2),MONTH(A2),15), DATE(YEAR(A2),MONTH(A2)+1,15)), IF(C2="ב", IF(DAY(A2)<=10, DATE(YEAR(A2),MONTH(A2),10), DATE(YEAR(A2),MONTH(A2)+1,10)), IF(OR(C2="ג",C2="ד",C2="ה",C2="ו"), A2, "לא מולא אות"))))

חכמון

@יוסי-מחשבים יש מדי הרבה סוגריים סוגרים בסוף.

יוסי מחשבים

@חכמון כתב בבקשת מידע | חישוב תאריך:

@יוסי-מחשבים יש מדי הרבה סוגריים סוגרים בסוף.

תוקן

חכמון

זה שלך:

=IF(C2="ז","", IF(C2="א", IF(DAY(A2)<=15,DATE(YEAR(A2),MONTH(A2),15),DATE(YEAR(EOMONTH(A2,0)),MONTH(EOMONTH(A2,0))+1,15)), IF(C2="ב", IF(DAY(A2)<=10,DATE(YEAR(A2),MONTH(A2),10),DATE(YEAR(EOMONTH(A2,0)),MONTH(EOMONTH(A2,0))+1,10)), IF(OR(C2="ג",C2="ד",C2="ה",C2="ו"), A2, "לא מולא אות"))))

וזה שלי:

=IF(C1="א",IF(A1>DATE(YEAR(A1),MONTH(A1),15),EDATE(DATE(YEAR(A1),MONTH(A1),15),1),DATE(YEAR(A1),MONTH(A1),15)),IF(C1="ב",IF(A1>DATE(YEAR(A1),MONTH(A1),10),EDATE(DATE(YEAR(A1),MONTH(A1),10),1),DATE(YEAR(A1),MONTH(A1),10)),IF(OR(C1="ג",C1="ד",C1="ה",C1="ו"),A1,IF(C1="ז","","לא מולא אות"))))

אכן הוא לא קיצר, חוץ ממה שהוא כתב קודם את ז ואז את האחרים.