::by @eliko2411
 
@echo off 
cd /d "%~dp0" && ( if exist "%temp%\getadmin.vbs" del "%temp%\getadmin.vbs" ) && reg.exe query "HKU\S-1-5-19" 1>nul 2>nul || (  cmd /u /c echo Set UAC = CreateObject^("Shell.Application"^) : UAC.ShellExecute "cmd.exe", "/k cd ""%~sdp0"" && ""%~s0""", "", "runas", 1 >> "%temp%\getadmin.vbs" && "%temp%\getadmin.vbs" && exit /B )
chcp 1255 >NUL
if exist check\backup goto restore

:backup
if not exist "driver_backup" mkdir driver_backup
mkdir driver_backup\check && echo eliko >driver_backup\check\backup
type %0 >driver_backup\driver_backup.bat
rem. >info.txt
(
echo to restore the drivers, run "driver_backup.bat" file Inside the folder "driver_backup".
echo. 
echo.

echo לשחזור/התקנת הדרייברים יש להריץ את הקובץ
echo "driver_backup.bat"
echo שבתוך התיקיה 
echo "driver_backup".
echo אם הקובץ
echo "driver_backup.bat"
echo ייתן שגיאה, אז להריץ את הקובץ 
echo "driver_backup.ps1"
echo באמצעות לחיצת עכבר ימנית ו
echo "run with powershell"
echo.
echo @eliko2411 
echo שמחתי להועיל..
echo בקרו בקבוצה
echo https://t.me/python_he 
echo ללימוד ודברים מעניינים )>>info.txt

dism /online /export-driver /destination:"%~dp0\driver_backup"
notepad info.txt & exit


:restore
echo Get-ChildItem "%~dp0" -Recurse -Filter ^"*.inf^" ^| ForEach-Object { PNPUtil.exe /add-driver $_.FullName /install } >driver_backup.ps1
powershell -executionpolicy bypass -File .\driver_backup.ps1



:end
echo.
echo.
echo.
echo DONE
echo Press any key to exit
pause >nul
exit
